REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION 21 *****

REM x limits: -.4150728, -.3319301
REM y limits: .625428, .687785

SCREEN 12

iterationlimit = 10000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

xcentre = (-.419092 - .327911) / 2
ylow = .625428
yhigh = .687785
xlow = xcentre - (yhigh - ylow) / 2 * 4 / 3
xhigh = xcentre + (yhigh - ylow) / 2 * 4 / 3


FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 1000 THEN
                colour = yellow
            ELSEIF iterations > 560 THEN
                colour = lightred
            ELSEIF iterations > 480 THEN
                colour = lightgreen
            ELSEIF iterations > 420 THEN
                colour = lightblue
            ELSEIF iterations > 300 THEN
                colour = white
            ELSEIF iterations MOD 100 >= 90 THEN
                colour = lightmagenta
            ELSEIF iterations MOD 100 >= 80 THEN
                colour = lightcyan
            ELSEIF iterations MOD 100 >= 70 THEN
                colour = brown
            ELSEIF iterations MOD 100 >= 60 THEN
                colour = green
            ELSEIF iterations MOD 100 >= 50 THEN
                colour = magenta
            ELSEIF iterations MOD 100 >= 40 THEN
                colour = blue
            ELSEIF iterations MOD 100 >= 30 THEN
                colour = red
            ELSEIF iterations MOD 100 >= 20 THEN
                colour = lightgrey
            ELSEIF iterations MOD 100 >= 10 THEN
                colour = cyan
            ELSEIF iterations MOD 100 >= 0 THEN
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)