REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #20 *****

REM x limits: .3826909, .4824621
REM y limits: .3063293, .3811577

REM ***** A VIEW FROM THE EAST *****

SCREEN 12

iterationlimit = 10000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

xcentre = (.386986 + .478167) / 2
ylow = .318065
yhigh = .380422
ycentre = (ylow + yhigh) / 2
ylow = ycentre - (ycentre - ylow) * 1.2 - .0055
yhigh = ycentre + (yhigh - ycentre) * 1.2 - .0055
xlow = xcentre - (yhigh - ylow) / 2 * 4 / 3
xhigh = xcentre + (yhigh - ylow) / 2 * 4 / 3


FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 100 THEN
                colour = yellow
            ELSEIF iterations > 56 THEN
                colour = lightred
            ELSEIF iterations > 48 THEN
                colour = lightgreen
            ELSEIF iterations > 42 THEN
                colour = lightblue
            ELSEIF iterations > 30 THEN
                colour = white
            ELSEIF iterations MOD 10 = 9 THEN
                colour = lightmagenta
            ELSEIF iterations MOD 10 = 8 THEN
                colour = lightcyan
            ELSEIF iterations MOD 10 = 7 THEN
                colour = brown
            ELSEIF iterations MOD 10 = 6 THEN
                colour = green
            ELSEIF iterations MOD 10 = 5 THEN
                colour = magenta
            ELSEIF iterations MOD 10 = 4 THEN
                colour = blue
            ELSEIF iterations MOD 10 = 3 THEN
                colour = red
            ELSEIF iterations MOD 10 = 2 THEN
                colour = lightgrey
            ELSEIF iterations MOD 10 = 1 THEN
                colour = cyan
            ELSEIF iterations MOD 10 = 0 THEN
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)