REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #16 *****

REM x limits: -.4817377, -.4815377
REM y limits: .6154107, .6155607

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

oldylow = .6132143
oldyhigh = .6162143
oldxlow = -.4834783
oldxhigh = -.4794783

oldyrange = oldyhigh - oldylow
oldxrange = oldxhigh - oldxlow

ycentre = oldylow + (oldyrange) * 15.9 / 21
xcentre = oldxlow + (oldxrange) * 12.7 / 27.6

scalefactor = 1 / 20

yrange = oldyrange * scalefactor
xrange = oldxrange * scalefactor

ylow = ycentre - yrange / 2: REM 0.6139643
yhigh = ycentre + yrange / 2: REM 0.6154643
xlow = xcentre - xrange / 2: REM -0.4824783
xhigh = xcentre + xrange / 2: REM -0.4804783

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 225 THEN
                colour = yellow
            ELSEIF iterations > 150 THEN
                colour = lightred
            ELSEIF iterations > 100 THEN
                colour = lightgreen
            ELSEIF iterations > 80 THEN
                colour = lightblue
            ELSEIF iterations > 70 THEN
                colour = white
            ELSEIF iterations MOD 10 = 9 THEN
                colour = lightmagenta
            ELSEIF iterations MOD 10 = 8 THEN
                colour = lightcyan
            ELSEIF iterations MOD 10 = 7 THEN
                colour = brown
            ELSEIF iterations MOD 10 = 6 THEN
                colour = green
            ELSEIF iterations MOD 10 = 5 THEN
                colour = magenta
            ELSEIF iterations MOD 10 = 4 THEN
                colour = blue
            ELSEIF iterations MOD 10 = 3 THEN
                colour = red
            ELSEIF iterations MOD 10 = 2 THEN
                colour = lightgrey
            ELSEIF iterations MOD 10 = 1 THEN
                colour = cyan
            ELSEIF iterations MOD 10 = 0 THEN
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)