REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #12, variation C *****

REM x limits: -.1758936, -.1425603
REM y limits: 1.020833, 1.045833

REM Mini-mand. off top of top blob

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

ylow = -1.25
yhigh = 1.25
xlow = -2.78
xhigh = xlow + (yhigh - ylow) * 4 / 3

ycentrenew = ylow + (yhigh - ylow) * 19.18 / 21
xcentrenew = xlow + (xhigh - xlow) * 21.7 / 27.6

yhalfrange = .125 / 10
xhalfrange = yhalfrange * 4 / 3

ylow = ycentrenew - yhalfrange
yhigh = ycentrenew + yhalfrange
xlow = xcentrenew - xhalfrange
xhigh = xcentrenew + xhalfrange

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 100 THEN
                colour = yellow
            ELSEIF iterations > 77 THEN
                colour = lightred
            ELSEIF iterations > 59 THEN
                colour = lightgreen
            ELSEIF iterations > 46 THEN
                colour = lightblue
            ELSEIF iterations > 35 THEN
                colour = white
            ELSEIF iterations MOD 10 = 9 THEN
                colour = lightmagenta
            ELSEIF iterations MOD 10 = 8 THEN
                colour = lightcyan
            ELSEIF iterations MOD 10 = 7 THEN
                colour = brown
            ELSEIF iterations MOD 10 = 6 THEN
                colour = green
            ELSEIF iterations MOD 10 = 5 THEN
                colour = magenta
            ELSEIF iterations MOD 10 = 4 THEN
                colour = blue
            ELSEIF iterations MOD 10 = 3 THEN
                colour = red
            ELSEIF iterations MOD 10 = 2 THEN
                colour = lightgrey
            ELSEIF iterations MOD 10 = 1 THEN
                colour = cyan
            ELSEIF iterations MOD 10 = 0 THEN
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)