REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #12, variation A *****

REM x limits: -.1758936, -.1425603
REM y limits: 1.020833, 1.045833

REM Mini-mand. off top of top blob

SCREEN 12

iterationlimit = 100

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

colour0 = 14
colour1 = 4
colour2 = 5
colour3 = 2
colour4 = 1
colour5 = 8
iterationlimitcolour = 0

ylow = -1.25
yhigh = 1.25
xlow = -2.78
xhigh = xlow + (yhigh - ylow) * 4 / 3

ycentrenew = ylow + (yhigh - ylow) * 19.18 / 21
xcentrenew = xlow + (xhigh - xlow) * 21.7 / 27.6

yhalfrange = .125 / 10
xhalfrange = yhalfrange * 4 / 3

ylow = ycentrenew - yhalfrange
yhigh = ycentrenew + yhalfrange
xlow = xcentrenew - xhalfrange
xhigh = xcentrenew + xhalfrange

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 20 THEN
                colour = colour0
            ELSEIF iterations > 6 THEN
                colour = colour1
            ELSEIF iterations > 4 THEN
                colour = colour2
            ELSEIF iterations > 2 THEN
                colour = colour3
            ELSEIF iterations > 1 THEN
                colour = colour4
            ELSE
                colour = colour5
            END IF
        ELSE
            colour = 0
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)