REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #11 *****

REM x limits: -.7454654, -.7453887
REM y limits: -.1130348, -.1129774

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

ycentre = -.1130061
xcentre = -.7454271
xrange = 7.66267E-05
yrange = xrange * 3 / 4

ylow = ycentre - yrange / 2
yhigh = ycentre + yrange / 2
xlow = xcentre - xrange / 2
xhigh = xcentre + xrange / 2

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 400 THEN
                colour = yellow
            ELSEIF iterations > 318 THEN
                colour = lightred
            ELSEIF iterations > 253 THEN
                colour = lightgreen
            ELSEIF iterations > 201 THEN
                colour = lightblue
            ELSEIF iterations > 160 THEN
                colour = white
            ELSEIF iterations > 127 THEN
                colour = lightmagenta
            ELSEIF iterations > 101 THEN
                colour = lightcyan
            ELSEIF iterations > 80 THEN
                colour = brown
            ELSEIF iterations > 73 THEN
                colour = green
            ELSEIF iterations > 64 THEN
                colour = magenta
            ELSEIF iterations > 51 THEN
                colour = blue
            ELSEIF iterations > 48 THEN
                colour = red
            ELSEIF iterations > 46 THEN
                colour = lightgrey
            ELSEIF iterations > 45 THEN
                colour = cyan
            ELSE
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)