REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #9 *****

REM x limits: -.7455327, -.7450593
REM y limits: -.113236, -.112881

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

ylow = -.113236
yhigh = -.112881
xlow = (-.745054 - .745538) / 2 - (yhigh - ylow) * 4 / 3 / 2
xhigh = (-.745054 - .745538) / 2 + (yhigh - ylow) * 4 / 3 / 2

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 700 THEN
                colour = yellow
            ELSEIF iterations > 650 THEN
                colour = lightred
            ELSEIF iterations > 600 THEN
                colour = lightgreen
            ELSEIF iterations > 550 THEN
                colour = lightblue
            ELSEIF iterations > 500 THEN
                colour = white
            ELSEIF iterations > 450 THEN
                colour = lightmagenta
            ELSEIF iterations > 400 THEN
                colour = lightcyan
            ELSEIF iterations > 350 THEN
                colour = brown
            ELSEIF iterations > 300 THEN
                colour = green
            ELSEIF iterations > 250 THEN
                colour = magenta
            ELSEIF iterations > 200 THEN
                colour = blue
            ELSEIF iterations > 150 THEN
                colour = red
            ELSEIF iterations > 100 THEN
                colour = lightgrey
            ELSEIF iterations > 50 THEN
                colour = cyan
            ELSE
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)