REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #8, variation B *****

REM x limits: -.7454203, -.745039
REM y limits: -.1127465, -.1124605

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

ycentre = -(.11196 + .11339) / 2
yhalfrange = (.11339 - .11196) / 2 / 5
ylow = ycentre - yhalfrange + yhalfrange / 2
yhigh = ycentre + yhalfrange + yhalfrange / 2
xlow = (-.74448 - .74591) / 2 - (yhigh - ylow) * 4 / 3 / 2
xhigh = (-.74448 - .74591) / 2 + (yhigh - ylow) * 4 / 3 / 2
xrange = xhigh - xlow
xlow = xlow - xrange / 11
xhigh = xhigh - xrange / 11

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 600 THEN
                colour = yellow
            ELSEIF iterations > 430 THEN
                colour = lightred
            ELSEIF iterations > 300 THEN
                colour = lightgreen
            ELSEIF iterations > 200 THEN
                colour = lightblue
            ELSEIF iterations > 120 THEN
                colour = white
            ELSEIF iterations MOD 20 >= 18 THEN
                colour = lightmagenta
            ELSEIF iterations MOD 20 >= 16 THEN
                colour = lightcyan
            ELSEIF iterations MOD 20 >= 14 THEN
                colour = brown
            ELSEIF iterations MOD 20 >= 12 THEN
                colour = green
            ELSEIF iterations MOD 20 >= 10 THEN
                colour = magenta
            ELSEIF iterations MOD 20 >= 8 THEN
                colour = blue
            ELSEIF iterations MOD 20 >= 6 THEN
                colour = red
            ELSEIF iterations MOD 20 >= 4 THEN
                colour = lightgrey
            ELSEIF iterations MOD 20 >= 2 THEN
                colour = cyan
            ELSEIF iterations MOD 20 >= 0 THEN
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)