REM ***** MAD TEDDY'S MANDELBROT SET SERIES: REGION #8 *****

REM x limits: -.7461483, -.7442417
REM y limits: -.11339, -.11196

SCREEN 12

iterationlimit = 1000

black = 0
blue = 1
green = 2
cyan = 3
red = 4
magenta = 5
brown = 6
lightgrey = 7
darkgrey = 8
lightblue = 9
lightgreen = 10
lightcyan = 11
lightred = 12
lightmagenta = 13
yellow = 14
white = 15

ylow = -.11339
yhigh = -.11196
xlow = (-.74448 - .74591) / 2 - (yhigh - ylow) * 4 / 3 / 2
xhigh = (-.74448 - .74591) / 2 + (yhigh - ylow) * 4 / 3 / 2

FOR i = 0 TO 479
    FOR j = 0 TO 639
        x = xlow + j * (xhigh - xlow) / 639
        y = yhigh - i * (yhigh - ylow) / 479
        xc = x: yc = y
        iterations = 0
        rsquared = 0
        DO UNTIL rsquared >= 4 OR iterations > iterationlimit
            u = x * x - y * y + xc
            v = 2 * x * y + yc
            rsquared = u * u + v * v
            x = u: y = v
            iterations = iterations + 1
        LOOP
        IF rsquared >= 4 THEN
            IF iterations > 160 THEN
                colour = yellow
            ELSEIF iterations > 150 THEN
                colour = lightred
            ELSEIF iterations > 140 THEN
                colour = lightgreen
            ELSEIF iterations > 130 THEN
                colour = lightblue
            ELSEIF iterations > 120 THEN
                colour = white
            ELSEIF iterations > 110 THEN
                colour = lightmagenta
            ELSEIF iterations > 100 THEN
                colour = lightcyan
            ELSEIF iterations > 90 THEN
                colour = brown
            ELSEIF iterations > 80 THEN
                colour = green
            ELSEIF iterations > 70 THEN
                colour = magenta
            ELSEIF iterations > 60 THEN
                colour = blue
            ELSEIF iterations > 50 THEN
                colour = red
            ELSEIF iterations > 40 THEN
                colour = lightgrey
            ELSEIF iterations > 30 THEN
                colour = cyan
            ELSE
                colour = darkgrey
            END IF
        ELSE
            colour = black
        END IF
        PSET (j, i), colour
    NEXT j
NEXT i

a$ = ""
DO: a$ = INKEY$: LOOP UNTIL a$ = CHR$(27)