REM     *****     RADIOLARIAN - COLOUR     *****

constreal = .5
constimag = 0

screenheight = 321
screenwidth = 429

aspectratio = screenwidth / screenheight: REM approx. 4/3

black = 0
red = 4
green = 2
yellow = 14

SCREEN 12: CLS : REM graphics screen, 640x480 pixels, 16 colours

ymax = 1.88
ymin = -ymax
xmax = ymax * aspectratio
xmin = -xmax

ilimit = screenheight - 1
jlimit = screenwidth - 1

FOR i = 0 TO ilimit
   FOR j = 0 TO jlimit
      x0 = xmin + (xmax - xmin) * j / jlimit
      y0 = -ymin - (ymax - ymin) * i / ilimit
      x = x0
      y = y0
      FOR n = 1 TO 100
         xx = x * (x * x - 3 * y * y) + constreal: REM this line and the next give the cube
         yy = y * (3 * x * x - y * y) + constimag: REM of the number, plus a constant
         x = xx
         y = yy
         IF ABS(x) > 10 OR ABS(y) > 10 OR x * x + y * y > 100 THEN
            n = 100
         END IF
      NEXT n
      IF ABS(x) > 10 AND ABS(y) > 10 THEN
         PSET (j, i), black
      ELSEIF ABS(x) > 10 AND ABS(y) <= 10 THEN
         PSET (j, i), red
      ELSEIF ABS(x) <= 10 AND ABS(y) > 10 THEN
         PSET (j, i), green
      ELSE
         PSET (j, i), yellow
      END IF
   NEXT j
NEXT i

a$ = ""
DO
   a$ = INKEY$
LOOP UNTIL a$ = CHR$(27): REM wait until Esc is pressed to end the program